Usar XSL para pasar de un nodo a otro

Entonces quiero convertir lo siguiente usando XSL

<doc>
    <data id="priority" level="2" include="true">
        <name>Priority</name>
    </data>
    <data id="cost" level="1" leveltype="number">
        <name>Cost</name>
    </data>
    <data id="date" level="3" include="true">
        <name>Date</name>
    </data>
</doc>

A esto

<doc>
    <data id="priority">
        <name>Priority</name>
    </data>
    <data id="cost">
        <name>Cost</name>
    </data>
    <data id="date">
        <name>Date</name>
    </data>

    <!-- ordering matters, though if necessary I can reorder this manually via the DOM instead of XSL -->
    <levels>   
        <level id="cost" include="false" type="number"/>
        <level id="priority" include="true"/>
        <level id="date" include="true"/>
    </level>
</doc>

Básicamente, quiero tomar los atributos de nivel y hacerlos suyos. Una gran ventaja sería si hubiera alguna forma de eliminar el número de nivel y usar el orden del nodo para representarlo.

preguntado el 16 de mayo de 11 a las 19:05

Si puede agregar muestras de lo que tiene, así como muestras del resultado final, eso nos ayudaría a ayudarlo. -

Buena pregunta, +1. Vea mi respuesta para obtener una solución completa, breve y basada solo en plantillas: esta podría ser la más corta, simple y fácilmente extensible de todas las respuestas. -

4 Respuestas

Esta es una solución más corta y simple que usa solo plantillas (no <xsl:for-each>):

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="/*">
  <doc>
   <xsl:apply-templates select="*"/>
   <levels>
    <xsl:apply-templates select="data" mode="level">
     <xsl:sort select="@level" data-type="number"/>
    </xsl:apply-templates>
   </levels>
  </doc>
 </xsl:template>
 <xsl:template match="data/@*[not(name()='id')]"/>

 <xsl:template match="data" mode="level">
  <level id="{@id}" include="{boolean(@include)}">
   <xsl:if test="@leveltype">
    <xsl:attribute name="type"><xsl:value-of select="@leveltype"/></xsl:attribute>
   </xsl:if>
  </level>
 </xsl:template>
</xsl:stylesheet>

Cuando se aplica en el documento XML proporcionado:

<doc>
    <data id="priority" level="2" include="true">
        <name>Priority</name>
    </data>
    <data id="cost" level="1" leveltype="number">
        <name>Cost</name>
    </data>
    <data id="date" level="3" include="true">
        <name>Date</name>
    </data>
</doc>

se produce el resultado deseado y correcto:

<doc>
   <data id="priority">
      <name>Priority</name>
   </data>
   <data id="cost">
      <name>Cost</name>
   </data>
   <data id="date">
      <name>Date</name>
   </data>
   <levels>
      <level id="cost" include="false" type="number"/>
      <level id="priority" include="true"/>
      <level id="date" include="true"/>
   </levels>
</doc>

Explicación:

  1. Usar y anular la regla / plantilla de identidad.

  2. Usar mode="level" para generar la segunda parte del documento de resultado.

contestado el 17 de mayo de 11 a las 17:05

+1. He vagado un rato buscando una solución sin xsl:for-each. - Emiliano Poggi

@empo: Gracias: uso <xsl:for-each> (casi) solo en el caso de que sea necesario cambiar el documento actual a otro para que el key() La función funcionaría con el segundo documento. Aparte de este caso de uso, no creo que haya ninguna otra situación en la que <xsl:for-each> es necesario. - Dimitre Novatchev

suena simple! Pensaré en esto la próxima vez que usaré un bucle. - Emiliano Poggi

@ToddMyhre: Sí, el mode atributo puede ser muy útil en tales casos. - Dimitre Novatchev

Solo una variante:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

<xsl:template match="doc">

 <doc>

  <!-- build and sort data nodes -->
  <xsl:for-each select="data">
   <xsl:sort select="@id"/>
    <data id="{@id}">
     <xsl:copy-of select="name"/>
    </data>
   </xsl:for-each>

   <!-- build and sort levels -->
   <levels>
    <xsl:for-each select="data">
     <xsl:sort select="@id"/>
      <level id="{@id}" include="{boolean(@include)}">
       <xsl:if test="@leveltype">
        <xsl:attribute name="type">
         <xsl:value-of select="@leveltype"/>
        </xsl:attribute>
       </xsl:if>
      </level>
    </xsl:for-each>
   </levels>

 </doc>

 </xsl:template>
</xsl:stylesheet>

contestado el 17 de mayo de 11 a las 11:05

Esta es la solucion:

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:strip-space elements="*"/>
  <xsl:output indent="yes"/>

  <!-- attribute suppression template -->
  <xsl:template match="@*" priority="2"/>

  <xsl:template match="/doc">
    <xsl:copy>
      <xsl:apply-templates select="*" mode="data"/>
      <levels>
        <xsl:apply-templates select="*" mode="levels">
          <xsl:sort select="@level" data-type="number"/>
        </xsl:apply-templates>
      </levels>
    </xsl:copy>
  </xsl:template>


  <xsl:template match="@*|node()" mode="data">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()" mode="data"/>
    </xsl:copy></xsl:template><!-- identity template -->

  <xsl:template match="@*" mode="data"/><!-- suppress -->
  <xsl:template match="@id" mode="data" priority="2"><!-- keep -->
    <xsl:copy-of select="."/></xsl:template>


  <xsl:template match="@*|node()" mode="levels">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()" mode="levels"/>
    </xsl:copy></xsl:template><!-- identity template -->

  <xsl:template match="data" mode="levels">
    <level>
      <xsl:apply-templates select="@*" mode="levels"/>
    </level></xsl:template>

  <xsl:template match="@level" mode="levels"/><!-- suppress -->
  <xsl:template match="@leveltype" mode="levels"><!-- rename -->
    <xsl:attribute name="type"><xsl:value-of select="."/>
    </xsl:attribute></xsl:template>

</xsl:stylesheet>

yo asumo eso <level id="cost" include="false" type="number"/> en su salida esperada hay un artefacto de copiar / pegar ya que el atributo falta en level[@id="cost"] en la entrada.

contestado el 16 de mayo de 11 a las 23:05

Puede ser una forma más sencilla:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
    <doc>
        <xsl:for-each select="doc/data">
            <data>
                <xsl:attribute name="id">
                    <xsl:value-of select="@id"/>
                </xsl:attribute>
                <name><xsl:value-of select="name" /></name>
            </data>
        </xsl:for-each>
        <levels>
            <xsl:for-each select="doc/data">
                <xsl:sort select="@level" />
                <level>
                    <xsl:attribute name="id">
                        <xsl:value-of select="@id"/>
                    </xsl:attribute>
                    <xsl:choose>
                        <xsl:when test="@include='true'">
                            <xsl:attribute name="include">true</xsl:attribute>
                        </xsl:when>
                        <xsl:otherwise>
                            <xsl:attribute name="include">false</xsl:attribute>
                        </xsl:otherwise>
                    </xsl:choose>
                </level>
            </xsl:for-each>
        </levels>
    </doc>
</xsl:template>
</xsl:stylesheet>

contestado el 16 de mayo de 11 a las 23:05

No es la respuesta que estás buscando? Examinar otras preguntas etiquetadas or haz tu propia pregunta.