copia de xml a xml con reemplazo de [campo]

hola chicos, he tenido algunos problemas con el suyo. Quiero hacer una copia completa de un xml y reemplazar un campo dentro de los datos. Este es el código que he estado usando, pero solo transforma el primer campo y no copia el xml estoy usando eclipse con la transformación xsl predeterminada para hacer el trabajo, ya que parece que es el único procesador que puedo hacer funcionar correctamente de todos modos, aquí está la plantilla xsl:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
    <xsl:variable name="replacedURL">
        <xsl:call-template name="string-replace-all">
            <xsl:with-param name="text" select="/hotels/hotel/hotel_link/text()"/>
            <xsl:with-param name="replace" select="'[[PARTNERID]]'"/>
            <xsl:with-param name="by" select="'13252'"/>
        </xsl:call-template>
    </xsl:variable>
    <xsl:value-of select="$replacedURL"/>
</xsl:template>
<xsl:template name="string-replace-all">
    <xsl:param name="text"/>
    <xsl:param name="replace"/>
    <xsl:param name="by"/>
    <xsl:choose>
        <xsl:when test="contains($text, $replace)">
            <xsl:value-of select="substring-before($text,$replace)"/>
            <xsl:value-of select="$by"/>
            <xsl:call-template name="string-replace-all">
                <xsl:with-param name="text" select="substring-after($text,$replace)"/>
                <xsl:with-param name="replace" select="$replace"/>
                <xsl:with-param name="by" select="$by"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>
</xsl:stylesheet>

entonces esta es una muestra del xml

<hotel>
<hotel_ref>235128</hotel_ref>
<hotel_name>Afghanistan Dolores test - non bookable</hotel_name>
<hotel_star>2</hotel_star>
<hotel_address>afghanistan test</hotel_address>
<hotel_city>afghanistan</hotel_city>
<hotel_pcode /><hotel_county />
<hotel_country>Afghanistan</hotel_country>
<hotel_description>hotel description text</hotel_description>
 <alternate_description>hotel description text</alternate_description>
 <hotel_directions>kjlaklka</hotel_directions>
 <alternate_directions>kjlaklka</alternate_directions>
<hotel_link> http://www.website.com/en/p[[PARTNERID]]/hotel-reservations/235128_afghanistan-dolores-test-non-bookable-afghanistan.aspx</hotel_link>
<customerrating>0</customerrating>
<PricesFrom>10.0000</PricesFrom>
<MaxPrice>800.00</MaxPrice>
<CurrencyCode>GBP</CurrencyCode>
<images />
<geo_code><lat>34.53824</lat><long>69.18640</long></geo_code>
<hotel_facilities />
<checkin_time>12/07/2011 14:00:00</checkin_time>
<checkout_time>12/07/2011 11:00:00</checkout_time>
 <cancellationpolicy>2 days prior to stay</cancellationpolicy>
<cancellationtext /><accommodation_type /><hotel_appeals />
<hotel_star_accreditor />
<hotel_total_rooms>45</hotel_total_rooms>
<hotel_credit_cards>
<CreditCard><credit_card_id>4</credit_card_id><credit_card_name>American Express</credit_card_name></CreditCard><CreditCard><credit_card_id>5</credit_card_id><credit_card_name>Switch/Maestro</credit_card_name></CreditCard><CreditCard><credit_card_id>1</credit_card_id><credit_card_name>Visa/Delta</credit_card_name></CreditCard><CreditCard><credit_card_id>2</credit_card_id> <credit_card_name>Mastercard</credit_card_name></CreditCard></hotel_credit_cards>  
<hotel_city_taxes><CityTax><Type /><Value /><OptedIn /><IsCityTaxArea /></CityTax>
</hotel_city_taxes> 
</hotel>

el archivo completo tiene alrededor de 500 megabytes. ¿Necesitaría un procesador especial para hacer esto o los eclipses incorporados en la transformación xsl harían el trabajo?

preguntado el 27 de julio de 12 a las 17:07

AFAIK, oXygen se puede usar como un complemento de eclipse. En este caso, puede usar oXygen con Saxon 9.x y ejecutar la solución basada en RegEx XSLT 2.0 que le di para su pregunta anterior. -

1 Respuestas

Copiar todo y modificar solo una pequeña pieza siempre es un caso para la plantilla de identidad:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <!-- identity template: copy everything 1:1 -->
  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()" />
    </xsl:copy>
  </xsl:template>

  <!-- ...except for the text in <hotel_link> elements: -->
  <xsl:template match="hotel_link/text()">
    <xsl:call-template name="string-replace-all">
      <xsl:with-param name="text"    select="."/>
      <xsl:with-param name="replace" select="'[[PARTNERID]]'"/>
      <xsl:with-param name="by"      select="'13252'"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="string-replace-all">
    <xsl:param name="text"/>
    <xsl:param name="replace"/>
    <xsl:param name="by"/>
    <xsl:choose>
      <xsl:when test="contains($text, $replace)">
        <xsl:value-of select="substring-before($text,$replace)"/>
        <xsl:value-of select="$by"/>
        <xsl:call-template name="string-replace-all">
          <xsl:with-param name="text" select="substring-after($text,$replace)"/>
          <xsl:with-param name="replace" select="$replace"/>
          <xsl:with-param name="by" select="$by"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$text"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

(La string-replace-all la plantilla ha sido tomado de esta respuesta.)

Dicho esto, si su archivo de entrada tiene 500 MB, no debe usar una transformación XSLT, ya que crea un DOM completo de la entrada en la memoria antes de que pueda comenzar. Un DOM siempre es mucho más grande que el documento XML en el que se basa, por lo que podría tener problemas de memoria aquí. Por supuesto que puedes intentarlo de todos modos.

Debería escribir un pequeño analizador SAX en su lugar. Esto será más rápido y más eficiente en memoria.

contestado el 23 de mayo de 17 a las 12:05

eso pareció funcionar. Lo ejecuté a través de la transformación xsl de eclipse con xalan como procesador. Recibí una advertencia quejándose de una conexión de socket fallida después de 60 intentos. Tenía el eclipse .ini configurado en 4GB. eso con la pérdida de caracteres, así que creo que aunque tuve un error, se completó con éxito, gracias por su ayuda. dom

No es la respuesta que estás buscando? Examinar otras preguntas etiquetadas or haz tu propia pregunta.