Elija el color de un Picturebox con SizeMode ZOOM

¿Cómo obtener el color de un punto (ubicación del cursor del mouse) de un cuadro de imagen ZOOMed?

Mi código actual que no funciona

Private Sub pickColor(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles picBox.MouseClick
    Dim TempBitmap As New Bitmap(picBox.Image)
    Dim MyColor As Color
    MyColor = TempBitmap.GetPixel(e.X, e.Y)
End Sub

preguntado el 28 de julio de 12 a las 16:07

2 Respuestas

Puedes probar algo como esto:

Private Sub pickColor(ByVal sender As Object, ByVal e As MouseEventArgs) _
                      Handles picBox.MouseClick
  Using bmp As New Bitmap(picBox.ClientSize.Width, _
                          picBox.ClientSize.Height)
    picBox.DrawToBitmap(bmp, picBox.ClientRectangle)
    MessageBox.Show(bmp.GetPixel(e.X, e.Y).ToString())
  End Using
End Sub

Respondido 30 Jul 12, 17:07

No sabía que hay un método llamado DrawToBitmap. @LatsTech es mucho mejor que el mío. Mi solución simplemente intenta recrear lo que Picturebox tiene en Bitmap.

 Private Sub PictureBox1_MouseClick(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles PictureBox1.MouseClick
    Dim bits As New Bitmap(PictureBox1.Width, PictureBox1.Height)
    Dim context As Graphics = Graphics.FromImage(bits)

    '' Create picturebox background
    context.FillRectangle(New SolidBrush(PictureBox1.BackColor), _
                          0, 0, bits.Width, bits.Height)

    '' Try to reproduce zoomed image thumbnail
    Dim ratio As Double = 1.0
    Dim imageWidth As Integer = PictureBox1.Image.Width
    Dim imageHeight As Integer = PictureBox1.Image.Height

    If imageWidth > bits.Width Then
        ratio = bits.Width / imageWidth

        imageWidth = bits.Width
        imageHeight *= ratio
    End If

    If imageHeight > bits.Height Then
        ratio = bits.Height / imageHeight

        imageHeight = bits.Height
        imageWidth *= ratio
    End If

    context.DrawImage(PictureBox1.Image, _
                      New Rectangle((bits.Width - imageWidth) / 2, _
                                    (bits.Height - imageHeight) / 2, _
                                    imageWidth, imageHeight), _
                      New Rectangle(0, 0, PictureBox1.Image.Width, _
                                    PictureBox1.Image.Height), _
                      GraphicsUnit.Pixel)

    MsgBox(bits.GetPixel(e.X, e.Y).ToString)
End Sub

Respondido 30 Jul 12, 17:07

El código se ve genial pero es un poco más largo que el anterior, un voto de +1 :) - Sourav

No es la respuesta que estás buscando? Examinar otras preguntas etiquetadas or haz tu propia pregunta.