Hyperlinks do not jump in RichView

I'm working on a Delphi chat application that allows for a user to send hyperlinks in addition to regular text. I'm using a RichViewEdit to display the text. When a user sends the link, it should show up as a different color and be clickable so that, when clicked, it opens the default web browser.

I've read through the RichView documentation (which isn't really great) and I can't seem to figure out how to get the OnMouseMove and OnJump to work, any suggestions or help?

OnJump:

procedure TADComClient.RichViewJump(Sender: TObject; id: Integer);
var
  ItemNo: Integer;
  RVData: TCustomRVFormattedData;
  Link: PWideChar;
  URL: String;
begin
  RichView.GetJumpPointLocation(id, RVData, ItemNo);
  URL := RichView.GetItemText(ItemNo);
  ShellExecute(Application.Handle, 'open', PChar(URL), '', '', SW_SHOWNORMAL);
end;

preguntado el 31 de julio de 12 a las 15:07

Is the event actually firing? IIRC RichViewEdit jumps on a Ctrl-Click, not just a click, especially when editing the contents. -

The code below works, but I ended up using just RichView and not the edit because I had no need of the edit ability. -

1 Respuestas

This should get you where you need to go: {{ Article:

Adding URL hyperlink functionality to RichEdit

http://delphi.about.com/library/weekly/aa111803a.htm

Here's how to add URL hyperlink functionality to a TRichEdit component -
whenever the text in a RichEdit matches the format of a URL, the control
will display it as a hyperlink. Even more: when you click the URL, your
Web browser will be launched and the link will be loaded into the browser;
or if the URL is a "mailto:" link, your default email client will be launched,
thus enabling you to send e-mail messages "from" RichEdit.
}

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ComCtrls;

type
  TForm1 = class(TForm)
    RichEdit1: TRichEdit;
    RichEdit2: TRichEdit;
//    RichEdit1: TRichEdit;
//    RichEdit2: TRichEdit;
    procedure FormCreate(Sender: TObject);
  private
    procedure InitRichEditURLDetection(RE : TRichEdit);
  public
    { Public declarations }
  protected
    procedure WndProc(var Msg: TMessage); override;
  end;

var
  Form1: TForm1;

implementation
{$R *.dfm}

uses ShellApi, RichEdit;

procedure TForm1.InitRichEditURLDetection(RE: TRichEdit);
var
  mask: Word;
begin
  mask := SendMessage(RE.Handle, EM_GETEVENTMASK, 0, 0);
  SendMessage(RE.Handle, EM_SETEVENTMASK, 0, mask or ENM_LINK);
  SendMessage(RE.Handle, EM_AUTOURLDETECT, Integer(True), 0);
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  s: string;
begin
  InitRichEditURLDetection(RichEdit1);

  s:='Great Delphi tutorials and articles at ' +
     'http://www.delphi.about.com.' + #13#10 +
     'About Delphi Programming site!' + #13#10 +
     'Send an email to your Guide: mailto:delphi.guide@about.com';
  RichEdit1.Text := s;

  s:= 'http://www.delphi.about.com. ' +
      ' This Rich Edit does not recognize URLs!';
  RichEdit2.Text := s
end;

procedure TForm1.WndProc(var Msg: TMessage);
var
  p: TENLink;
  sURL: string;
  CE : TRichEdit;
begin
 if (Msg.Msg = WM_NOTIFY) then
 begin
  if (PNMHDR(Msg.lParam).code = EN_LINK) then
  begin
   p := TENLink(Pointer(TWMNotify(Msg).NMHdr)^);
   if (p.Msg = WM_LBUTTONDOWN) then
   begin
    try
     CE := TRichEdit(Form1.ActiveControl);
     SendMessage(CE.Handle, EM_EXSETSEL, 0, Longint(@(p.chrg)));
     sURL := CE.SelText;
     ShellExecute(Handle, 'open', PChar(sURL), 0, 0, SW_SHOWNORMAL);
    except
    end;
   end;
  end;
 end;

 inherited;
end; (* TForm1.WndProc *)

end. (* unit1.pas *)


{
********************************************
Zarko Gajic
About.com Guide to Delphi Programming
http://delphi.about.com
email: delphi.guide@about.com
free newsletter: http://delphi.about.com/library/blnewsletter.htm
forum: http://forums.about.com/ab-delphi/start/
********************************************
}

Respondido 31 Jul 12, 18:07

No es la respuesta que estás buscando? Examinar otras preguntas etiquetadas or haz tu propia pregunta.